Skip to main content
 首页 » 编程设计

python之对于格式错误的 python 代码,sed 中的 camelCase 到 snake_case

2025年05月04日9kevingrace

我有一些用驼峰命名法编写的 python 代码,但是根据 PEP 8变量名应该写在 snake_case 中。我写了一个小的 sed 脚本,它设法接受任何小写字母\1,后跟一个大写字母\2,然后把它变成\1_ 和一个小写字母\2

find . -iname \*.py | xargs sed -i "s/\([a-z]\)\([A-Z]\)/\1_\L\2/g" 

但是这会将 CamelCase 变成 Camel_case。据同PEP 8标准类名应以大写字母开头的 CamelCase 书写。

我如何编写不使用 CamelCase 但将 camelCamelCamelCamel... 翻译成 camel_camel_camel_camel... 的 sed 脚本?

我有一种感觉,我正在达到正则表达式的极限,因为我必须为未知数量的“驼峰”保留以小写字母开头的单词的上下文。我知道我可以在另一个工具中做到这一点,但我想知道 sed 是否可以做到这一点。证明这是不可能的论据也足够了。

我正在使用 GNU sed 4.2.2

请您参考如下方法:

其中一条评论提到 autopep8 ,这可能是选择 OP 的方法,但在 sed 中尝试这样做很有启发意义(我的意思是这是一个有趣的谜题)。

这是可能的:

sed -r ':loop; /.*\<([a-z]+([A-Z][a-z]+)+)\>.*/ { h; s//\1/; s/([A-Z])/_\l\1/g; G; s/(.*)\n(.*)\<[a-z]+([A-Z][a-z]+)+\>(.*)/\2\1\4/; b loop }' 

代码是

:loop 
/.*\<([a-z]+([A-Z][a-z]+)+)\>.*/ { 
  h 
  s//\1/ 
  s/([A-Z])/_\l\1/g 
  G 
  s/(.*)\n(.*)\<[a-z]+([A-Z][a-z]+)+\>(.*)/\2\1\4/ 
  b loop 
} 

在这里,\<[a-z]+([A-Z][a-z]+)+\>匹配 dromedaryCase 术语。 \<和 \>是单词边界,以确保这 仅 匹配此类术语。这样做,在一个循环中:

  1. 如果该行包含 dromedaryCase 术语:
  2. 将整行保存到保持缓冲区
  3. 分离 dromedaryCase 术语。这使用了 // 的事实重复使用最后一个正则表达式,即来自 1 的正则表达式。
  4. 将所有大写字母替换为_后跟对应的小写字母(这使用 GNU 扩展名 \l ;否则您需要 y/ABCDEF.../abcdef.../ 命令来更改大小写)。模式空间现在包含与 dromedaryCase 项对应的 snake_case 项。
  5. 将保持缓冲区中的原始行附加到模式空间
  6. 在原始正则表达式的基础上,将模式空间拆分为相关部分:\1是 snake_case 项,\2是替换部分之前的原始行的一部分,\4是 dromedaryCaseTerm 之后的部分。然后按正确顺序重新组装这些部件。
  7. 循环直到替换行中的所有 dromedaryCase 术语。